Blog

How to efficiently move and delete files on D-Link DNS-313 NAS Drive

Tue, 17 May 2011 11:43:05 GMT

From time to time I have the need to delete or move a number of large files on my DNS-313 SHARECENTER™ 1-BAY NETWORK STORAGE drive. Using Windows Explorer, or even Command Prompt, is slow as! A more efficient method is to telnet into the NAS drive.

Starting telnet service

By default telnet is not available available on the DNS-313. To start the telnet service go to http://<your dns-313 name or ip address>/web/telnetd.asp.

Note that the telnet service needs to be restarted after a rebooting DNS-313 drive.

Connecting to DNS-313 with telnet

Start telnet and enter the following command.

open <your dns-313 name or ip address>

When prompted enter the login name of root and password 11111.

At this point you should have the following screen:

Enter the unlock code 5784468 and now have a standard telnet connection.

The operating system for DNS-313 is Linux. http://www.yolinux.com/TUTORIALS/unix_for_dos_users.html is good cheat sheet for the Windows/DOS users amongst us to get around this Linux box.

The following command will take us to the data directory on the drive.

cd /mnt/HD_a2

Remove Folder

The following Linux command will remove a folder.

rm –R <folder>

There is no progress indicator doing large removals; just an empty line. The # prompt will appear when the folder has been removed.

Move Folder or File

The following Linux command will move a folder or file.

mv SOURCE DEST

Goodbye BlogEngine; Hello Orchard - How To

Sun, 08 May 2011 23:07:23 GMT

My move from BlogEngine to Orchard was reasonably painless. That is except for the URL rewriting. Who ever invented RegEx should be shot.

The two posts I found most help for the move were:

To follow is a very short hand list of steps I took to replace BlogEngine with Orchard. Over time I will blog about each step in more detail.

Preparing for the move

Spider the existing site
- http://home.snafu.de/tilman/xenulink.html
Export – BlogML
- www.example.com/admin/Pages/Settings.aspx
- Bottom of page click Export button.
Download Site
- zip
- ftp
- unzip
Delete Site
- Delete from IIS
- Reboot
- Delete folder

Installing Orchard

Run Microsoft Web Platform Installer
Complete the Orchard setup page
Unpublish the default home page and create temporary one.
FTP google webmaster page
Adjust maxRequestLength in Web.Config.
- Defaults to 4096.
- In hindsight zipping the file would probably get around this.
Create Blog
Import BlogML module.
Import blog
- Comments are not automatically approved.
Reset maxRequestLength in Web.Config.
Setup URL rewrite
- Install module
- Go to www.example.com/Admin/Settings/Index to enable and define rules.
Enable LiveWriter support
- www.example.com/Admin/Modules/Features
- In Content Publishing section enable Remove Blog Publishing.

Create Generic Classes

Sun, 08 May 2011 17:26:39 GMT

A generic type is a single programming element that adapts to perform the same functionality for a variety of data types. When you define a generic class or procedure, you do not have to define a separate version for each data type for which you might want to perform that functionality.

Source: MSDN Generic Types in Visual Basic

No doubt you’ve already used generic classes list like List(Of T) but how do you create your own generic class? Lets take simply NumberRange example. The purpose of the class is to set a minimum and maximum value then test if a value is in this range. The following class does that for integers.

''' <summary>
''' Allows a range to be set for and test if a value is between that range.
''' </summary>
Public Class IntegerRangeWithoutGeneric

    Private mMinValue As Integer
    Private mMaxValue As Integer

    ''' <summary>
    ''' Initializes a new instance of the <see cref="IntegerRangeWithoutGeneric" /> class.
    ''' </summary>
    Public Sub New()
    End Sub

    ''' <summary>
    ''' Initializes a new instance of the <see cref="IntegerRangeWithoutGeneric" /> class while setting <see cref="MinValue"/> and <see cref="MaxValue"/>.
    ''' </summary>
    Public Sub New(ByVal minValue As Integer, ByVal maxValue As Integer)

        mMinValue = minValue
        mMaxValue = maxValue

    End Sub

    ''' <summary>
    ''' Returns True if <paramref name="value"/> is between <see cref="MinValue"/> and <see cref="MaxValue"/> inclusive.
    ''' </summary>
    Public Function IsValid(ByVal value As Integer) As Boolean

        Return value >= mMinValue AndAlso value <= mMaxValue

    End Function

    ''' <summary>
    ''' Gets or sets the Minimum value for the range.
    ''' </summary>
    Public Property MinValue() As Integer
        Get
            Return mMinValue
        End Get
        Set(ByVal value As Integer)
            mMinValue = value
        End Set
    End Property

    ''' <summary>
    ''' Gets or sets the Maximum value for the range.
    ''' </summary>
    Public Property MaxValue() As Integer
        Get
            Return mMaxValue
        End Get
        Set(ByVal value As Integer)
            mMaxValue = value
        End Set
    End Property

End Class

No doubt this class achieves what we want but now we need the same thing for testing number of type double. Sure we could copy and paste the code, do a search and replace of Integer for Double but you know that’s not the best way. So lets create a Generic class.

Public Class NumberRange(Of T)

    Private mMinValue As T
    Private mMaxValue As T

    Public Sub New()
    End Sub

    Public Sub New(ByVal minValue As T, ByVal maxValue As T)

        mMinValue = minValue
        mMaxValue = maxValue

    End Sub

    Public Function IsValid(ByVal value As T) As Boolean

        Return value >= mMinValue AndAlso value <= mMaxValue

    End Function

    Public Property MinValue() As T
        Get
            Return mMinValue
        End Get
        Set(ByVal value As T)
            mMinValue = value
        End Set
    End Property

    Public Property MaxValue() As T
        Get
            Return mMaxValue
        End Get
        Set(ByVal value As T)
            mMaxValue = value
        End Set
    End Property

End Class

To make the class generic the class deleclaration line was changed to NumberRange(Of T). The (Of T) tells the compilier when the class is created it must be initialised with the type we are going to test. For example:

Dim integerTest As New NumberRange(Of Integer)(1, 10)Dim doubleTest As New NumberRange(Of Double)(0.1, 0.9)

If integerTest.IsValid(2) Then
...
End If

If doubleTest.IsValid(0.5) Then
...
End If

Wouldn’t it be nice if it was quite that simple. Unfortunately with generic types the only recognised operator is equals (=) therefore for our IsValid method will not work. To get around this problem we will need to make the NumberRange class MustInherit.

Public MustInherit Class NumberRange(Of T)

    Private mMinValue As T
    Private mMaxValue As T

    Public MustOverride Function IsValid(ByVal value As T) As Boolean
    Public Sub New()
    End Sub

    Public Sub New(ByVal minValue As T, ByVal maxValue As T)

        mMinValue = minValue
        mMaxValue = maxValue

    End Sub

    Public Property MinValue() As T
        Get
            Return mMinValue
        End Get
        Set(ByVal value As T)
            mMinValue = value
        End Set
    End Property

    Public Property MaxValue() As T
        Get
            Return mMaxValue
        End Get
        Set(ByVal value As T)
            mMaxValue = value
        End Set
    End Property

End Class

Then for our IntegerRange class:

Public Class IntegerRangeWithGeneric
    Inherits NumberRange(Of Integer)

    Public Sub New()
    End Sub

    Public Sub New(ByVal minValue As Integer, ByVal maxValue As Integer)
        MyBase.New(minValue, maxValue)
    End Sub

    Public Overrides Function IsValid(ByVal value As Integer) As Boolean
        Return value >= Me.MinValue AndAlso value <= Me.MaxValue
    End Function

End Class

When you create the IntegerRangeWithGeneric class you get a helping hand from the IDE. When you press enter at the end of “Inherits NumberRange(Of Integer)” the IDE creates a stub of the IsValid method for you with the correct parameter type.

In wrapping up just a few quick notes on creating generic classes.

Its only convention to name the generic type as T. Our class could have been Class NumberRange(Of WhatEver)
You can have multiple generic types when declaring a class. eg NumberRange(Of TValue, TWhatEver).

Source Code with Unit Tests

CreatingGenericClasses.zip (18.09 kb)

Creating a MVC MapRoute for {year} as a root folder

Sun, 08 May 2011 17:26:38 GMT

By default an ASP.NET MVC application has one URL routing rule: {controller}/{action}/{id}. With this routing rule in place MVC will interpret the URL /products/edit/2 as: using the ProductsController execute the Edit method with ID parameter of 2. The ProductsController.Edit method is responsible for retrieving product 2 from the database and passing it onto to /Views/Products/Edit.aspx. Edit.aspx is responsible for displaying the edit form.

Not surprisingly MVC gives us the power add additional routing rules. Routing rules (including the default) are defined by RegisterRoutes method in global.asax.vb.

Creating a Route

New routes are created via the RoutesCollection.MapRoute method. There are several MapRoute overload method but for our situation we need only use this overload: MapRoute(name, url, defaults, constraints).

name: Unique name for the route.
url: URL we are routing with each part of the url enclosed in {}. eg {Controller}/{Action}/{Id}.
defaults: Anonymous object to defining default values for the route.
constraints: Anonymous object defining rules to define it the URL being tested can is valid for this map.

defaults

The defaults parameter in MapRoute is an anonymous object to define default values for items that may be used by the constraints and/or the controller. A typical defaults parameter is:

New With {.controller = <controller name>, .action = [Details|Edit|Create]}

constraints

The constraints parameter can accept a regular expression or class that implements IRouteConstraint. IRouteConstraint has one method to implement: Match. Match accepts serveral parameters but must return True or False. A typical contraints parameter is:

New With {.result = New MyConstraint()}

Requirements

In this post I’m going to explain how to implement routing to satisfy the following requirements. The main table in the application is a list of competitions. Each competition has a start date. Therefore it seems appropriate that the basic folder structure of the site is:

/{year} - Lists all the competitions in starting in <year>.
/{year}/Create – Create a new competition.
/{year}/{slug} - Show the details of the competition in <year> with <slug> name.
/{year}/{slug}/Edit – Edit the selected competition.

Handling the /{year} and /{year}/Create URL

routes.MapRoute( _
   name:="year", _
   url:="{year}/{action}", _
   defaults:=New With {.controller = "Competitions", .action = "Index"}, _
   constraints:=New With {.year = New YearConstraint("Index", "Create")} _
)

This routing rule will be used when a URL is /{year}, /{year}/Index or /{year}/Create. This is achieved by MVC testing the current URL against the url parameter for this routing rule and the YearConstraint.Match method returns True. If the routing rule passes these tests then the method defined by {action} will be executed against CompetitionsController.

Handling the /{year}/{slug} and /{year}/{slug}/Edit URL

routes.MapRoute( _
   name:="year/slug", _
   url:="{year}/{slug}/{action}", _
   defaults:=New With {.controller = "Competitions", .action = "Details"}, _
   constraints:=New With {.year = New YearConstraint("Details", "Edit")} _
)

When MVC processes the URL /2009/aus-open it will call CompetitionsController.Details(year:=2009, slug:”aus-open”). The Details method is called in this instance because it was defined as the default action and no action was defined in the URL.

A URL of form /2009/aus-open/Edit will call CompetitionsController.Edit(year:=2009, slug:=”aus-open”).

YearConstraint

Our YearConstraint class implements the IRouteConstraint interface and has the following constructor.

Public Sub New(ByVal ParamArray allowableActions As String())

    ReDim mAllowableActions(allowableActions.Length - 1)

    For index = 0 To allowableActions.Length - 1
        mAllowableActions(index) = allowableActions(index).ToLower
    Next

End Sub

The constuctor accepts a variable number of acceptable actions (eg Details, Index, Edit). It then stores them in lower case in the private field.

Public Function Match(ByVal httpContext As System.Web.HttpContextBase, ByVal route As System.Web.Routing.Route, ByVal parameterName As String, ByVal values As System.Web.Routing.RouteValueDictionary, ByVal routeDirection As System.Web.Routing.RouteDirection) As Boolean Implements System.Web.Routing.IRouteConstraint.Match

    Dim year As String = CStr(values("year"))
    Dim action As String = CStr(values("action"))

    Return Me.IsValidYear(year) AndAlso mAllowableActions.Contains(action.ToLower)

End Function

The above Match method is called by MVC each time our route rule passes the URL test. In this case we only need use the values dictionary to get the year and action values from the URL to perform our final test.

I hope this has helped you define your own routing rules.

Compressing CSS and JS files

Sun, 08 May 2011 17:26:38 GMT

There are 2 reasons why you want to compress your CSS and JS files before publishing your website:

Reduces the size of files to be downloaded on client’s machine. In my experience 10 to 20k, not much but every bit helps.
Reduces the number of files to download with help performance for the client as well.

First step in compressing the files is to combine the same type of file into one file. Good old DOS COPY command will do the job for you.

cmd /c copy /A file1.css+file2.css+file3.css temp.combined.css /B /Y

Thanks to eugensk00 on stackoverflow.com (How do I concatenate JavaScript files into one file?) for that piece of info.

Next step is to use YUI Compressor to strip out whitespace and the like.

java.exe -jar yuicompressor-2.4.2.jar --type css --verbose temp.combined.css -o min.css

Now just change your HTML to point to the compressed file and you’re set to go.

To follow is a VBScript file to run the process for me.

Option Explicit

Dim java, compressor, fso, shell, stylesFolder, scriptsFolder

java = "C:\Program Files\Java\jre6\bin\java.exe"
compressor = "C:\Program Files\YUI Compressor\2.4.2\build\yuicompressor-2.4.2.jar"
stylesFolder = "styles"
scriptsFolder = "scripts"

Set fso = CreateObject("Scripting.FileSystemObject")
Set shell = CreateObject("WScript.Shell")

CleanCssFolder
CombineCss "yui-reset-fonts-grids.css+yui-base-min.css+shCore.css+shThemeDefault.css"
CompressCss
CleanCssFolder

CleanJavaScriptFolder
CombineJavaScript "shCore.js+shBrushCSharp.js+shBrushCss.js+shBrushJScript.js" _
                            &"+shBrushSql.js+shBrushVb.js+shBrushXml.js+shLegacy.js"
CompressJavaScript
CleanJavaScriptFolder

' Delete the temp files from styles folder.
Sub CleanCssFolder

    CleanFolder stylesFolder
    
End Sub

' Delete the temp files from scripts folder.
Sub CleanJavaScriptFolder

    CleanFolder scriptsFolder
    
End Sub

' Delete all files in <subFolder> that starts with "compressed.".
Sub CleanFolder(subFolder)

    Dim folder, files, file
    
    Set folder = fso.GetFolder(subFolder)
    Set files = folder.Files
    
    For Each file in files
    
        If StartsWith(file.Name, "temp.") Then
            
            fso.DeleteFile file.Path
            
        End If
        
    Next
    
End Sub

' Combine the css files into temp.combined.css.
Sub CombineCss(fileNames)

    Combine fileNames, stylesFolder, "temp.combined.css"
    
End Sub

' Combine the js files into temp.combined.js.
Sub CombineJavaScript(fileNames)

    Combine fileNames, scriptsFolder, "temp.combined.js"
    
End Sub

' Combine <fileNames> in <subFolder> to <outputFileName>.
Sub Combine(fileNames, subFolder, outputFileName)

    Dim cmd
    
    cmd = "cmd /c copy /A {fileNames} {subFolder}\{outputFileName} /B /Y"

    ' Insert the sub folder into each of the file names.
    fileNames = subFolder & "\" & fileNames
    fileNames = Replace(fileNames, "+", "+{subFolder}\")
    
    cmd = Replace(cmd, "{fileNames}", fileNames)
    cmd = Replace(cmd, "{subFolder}", subFolder)
    cmd = Replace(cmd, "{outputFileName}", outputFileName)
  
    WScript.Echo "Combining files..."
    shell.Run cmd, 0, True

End Sub

' Compress the css files.
Sub CompressCss()

    Dim cmd
        
    cmd = CompressCommand("css", stylesFolder, "temp.combined.css", "min.css")
    WScript.Echo "Compressing temp.combined.css..."
    shell.Run cmd, 0, True

End Sub

' Compress the js files.
Sub CompressJavaScript()

    Dim cmd
        
    cmd = CompressCommand("js", scriptsFolder, "temp.combined.js", "min.js")
    
    ' todo: Temporary workaround. Compressor is breaking SyntaxHighlighter.
    ' cmd = "cmd /c copy {scriptsFolder}\temp.combined.js {scriptsFolder}\min.js"
    ' cmd = Replace(cmd, "{scriptsFolder}", scriptsFolder)
    
    WScript.Echo "Compressing temp.combined.js..."
    shell.Run cmd, 0, True

End Sub

' Returns the YUI compress command line.
Function CompressCommand(fileType, subFolder, inputFileName, outputFileName)

    CompressCommand = """{java}"" -jar ""{compressor}"" --type {fileType} --verbose ""{subFolder}\{inputFileName}"" -o ""{subFolder}\{outputFileName}"""
    CompressCommand = Replace(CompressCommand, "{java}", java)
    CompressCommand = Replace(CompressCommand, "{compressor}", compressor)
    CompressCommand = Replace(CompressCommand, "{fileType}", fileType)
    CompressCommand = Replace(CompressCommand, "{subFolder}", subFolder)
    CompressCommand = Replace(CompressCommand, "{inputFileName}", inputFileName)
    CompressCommand = Replace(CompressCommand, "{outputFileName}", outputFileName)
    
End Function

' Returns True if <text> starts with <startsWith>.
Function StartsWith(text, startsWithText)
    StartsWith = (Left(text, Len(startsWithText)) = startsWithText)
End Function

A LINQ to SQL Repository class for VB

Sun, 08 May 2011 17:26:37 GMT

There are blog posts to explain the Repository pattern better than I can. The following is an implementation of the Repository pattern tied to a LINQ to SQL DataContext.

''' <summary>
''' Abstract Repository Class.
''' </summary>
''' <typeparam name="TEntity">The type of the entity/business object.</typeparam>
''' <typeparam name="TKey">The type of the unique key/id in entity.</typeparam>
Public MustInherit Class Repository(Of TEntity As Class, TKey)

    Private mDataContext As DataContext

    ''' <summary>
    ''' Get the item from the database by its key field.
    ''' </summary>
    ''' <param name="key">Value to the unique key identifying the item to get.</param>
    Public MustOverride Function [Get](ByVal key As TKey) As TEntity

    ''' <summary>
    ''' Initializes a new instance of the <see cref="Repository(Of TEntity, TKey)" /> class.
    ''' </summary>
    ''' <param name="dataContext"><see cref="System.Data.Linq.DataContext"/></param>
    Public Sub New(ByVal dataContext As DataContext)
        mDataContext = dataContext
    End Sub

    ''' <summary>
    ''' Get all the items from the database.
    ''' </summary>
    Public Function Read() As IEnumerable(Of TEntity)
        Return Me.GetTable()
    End Function

    ''' <summary>
    ''' Add an item to the database on next call to save.
    ''' </summary>
    Public Sub Add(ByVal item As TEntity)
        Me.GetTable().InsertOnSubmit(item)
    End Sub

    ''' <summary>
    ''' Delete the item from the databases on next call to save.
    ''' </summary>
    ''' <param name="item">The item.</param>
    Public Sub Delete(ByVal item As TEntity)
        Me.GetTable().DeleteOnSubmit(item)
    End Sub

    ''' <summary>
    ''' Saves all pending changes to the database.
    ''' </summary>
    Public Sub Save()
        mDataContext.SubmitChanges()
    End Sub

    ''' <summary>
    ''' Returns <see cref="System.Data.Linq.Table(Of TEntity)"/>.
    ''' </summary>
    ''' <returns></returns>
    Private Function GetTable() As Table(Of TEntity)
        Return mDataContext.GetTable(Of TEntity)()
    End Function

End Class

The following is an implementation of the Repository class.

Public Class CompetitionsRepository
    Inherits Core.Repository(Of Competition, Integer)

    Public Sub New()
        MyBase.New(New CroquetScoresDataContext)
    End Sub

    Public Overrides Function [Get](ByVal key As Integer) As Competition
        Return (From comp In Me.Read Where comp.Key = key).SingleOrDefault
    End Function

End Class

And finally to use the class.

Sub UpdateCompetitionName()

    Dim repo As New CompetitionsRepository

    For Each competition In repo.Read

        competition.Name = competition.Name.ToUpper

    Next

    repo.Save()

End Sub

New Open Source Library

Sun, 08 May 2011 17:26:36 GMT

Just started a new Open Source Library at http://26tp.codeplex.com. Over time I’ll be moving my library code into this library. I’ll blog about major updates, classes and extension methods as they are release.

I hope you find the library useful and at a very least a good learning tool.

Unit testing, even the most trivial stuff, is important!

Sun, 08 May 2011 17:26:35 GMT

For the past 3 days I’ve started to learn and write PowerShell scripts. Its very different to programming in VB.NET or C# and its been hard work for what seem like simply tasks.

The mistake I make most is using commas to between parameters when calling a function. You don’t do that in PowerShell.

I’ve been writing Unit Tests well over a here now and have never doubted their benefit. And I’ve been trying to be more disciplined by using TDD but not always succeeding.

One of my doubts about TDD is some of the more trivial tests you are encouraged to write. For example you should test a method does throw an exception if the an argument value is unexpected. I’ve often thought what a waste of my time. Now that I’m writing in PowerShell can keep testing for argument values incorrectly I’ve truly found a benefit for all those tiny little tests.

Arrange, Act, Assert comments help focus your Unit Test

Sun, 08 May 2011 17:26:34 GMT

My first exposure to the Arrange, Act & Assert (AAA) pattern for Unit Test was with MVC. Originally I thought what a waste of comments. I recently did so reading on the AAA and saw the light. Effectively my unit tests followed this pattern but not always clearly the case. Now the first thing I do when creating a unit test is to insert the AAA comments.

<TestMethod()> Sub MethodName_ShouldReturnValue_WhenThisCase()

    ' Arrange

    ' Act

    ' Assert

End Sub

It truly helps my focus and makes my unit test clean when I start this way.

Do some Googlingly to find out more about AAA.

NSchema 0.2 - Introduction

Sun, 08 May 2011 17:26:33 GMT

Back in August 2009 I started creating NSchema. NSchema is yet another ORM so why did I write it? The main reason was performance. I felt that the top ORM open source solutions out there, namely NHibernate, were too slow. I wanted to develop an ORM that could run as near as quickly to has directly writing SQL code as possible.

NSchema 0.1 is up and working in production and overall I consider it a good framework. On the positive side:

9.5 for performance.
7 for usability.

On the negative:

The code base is a hack feast.
Not TDD and certainly not a unit test for every function.

The best way forward is to start with a clean code base and refer to NSchema 0.1 code base rather than try and clean it up. So its time to get on with it. Keep coming back to the NSchema 0.2 contents page to find out how things are progressing.

NSchema 0.2 - Contents

Sun, 08 May 2011 17:26:32 GMT

This page will be constantly updated during the development on NSchema 0.2.

Day	Time Spent	Blog
0	20 mins	Introduction to NSchema 0.2

Start Chrome with pages that were open when you last closed it

Sun, 08 May 2011 17:26:31 GMT

"%LocalAppData%\Google\Chrome\Application\chrome.exe" -restore-last-session

Restart PC and load applications

Sun, 08 May 2011 17:26:31 GMT

Even with Windows 7 (which I love by the way) it seems I still need to reboot my pc a handful times a day. Not pinned down way but its something to do with Visual Studio and unit tests; I think!

Big deal you say, just hit the reset button. Well my problem with that is I then have to load my applications up again. Of course I could just add links to the Startup folder but I don’t always want to load the applications. The solution is two batch installed on the desktop and a shortcut in the Startup folder.

Restart.bat

@echo off 

REM Create RunStartup.yes file so Startup.bat will know it should load the applications.
REM ------------------------------------------------------------------------------------
echo Start applications on reboot > RunStartup.yes

REM Restart the PC allowing the user to save documents etc.
REM -------------------------------------------------------
shutdown.exe /r /t 0

Restart.bat creates the RunStartup.yes file and then restarts your PC.

Startup.bat

@echo off
REM If no parameters passed to Startup.bat then run the applications.
REM -----------------------------------------------------------------
IF "%1"=="" GOTO RunStartup

REM Parameter was passed so goto requested label in batch file.
REM -----------------------------------------------------------
GOTO %1

:RunStartupIfFileExists

REM If RunStartup.yes file does not exist then nothing to do.
REM -----------------------------------------------------
IF NOT EXIST RunStartup.yes GOTO END

REM Delete the RunStartup file so Startup.bat does not automatically start
REM applications next time.
REM ----------------------------------------------------------------------
DEL RunStartup.yes

GOTO RunStartup

:RunStartup

start /d "C:\Program Files (x86)\TweetDeck" TweetDeck.exe
start /d "C:\Program Files (x86)\Microsoft Visual Studio 9.0\Common7\IDE\" devenv.exe
start /d "C:\Users\TimMurphy\AppData\Local\Google\Chrome\Application" chrome.exe -restore-last-session
start explorer "C:\Users\TimMurphy\Code" 

:End

Startup.bat runs the applications I’m usually working on. If the batch file is run without an parameter then the applications are loaded. If RunStartupIfFilesExists is passed to Startup.bat then the applications are only loaded if RunStartup.yes file exists.

The last file to this process it a shortcut in the Startup folder with the parameter RunStartupIfFileExists.

So now when I want to restart the PC and load my usual programs I just double-click Restart.bat on my desktop.

Code Snippet for Test Methods

Sun, 08 May 2011 17:26:30 GMT

I previously blog that Arrange Act Assert Comments help focus your unit test. Now for a code snippet to help implement that idea.

<?xml version="1.0" encoding="UTF-8"?>
<CodeSnippets xmlns="http://schemas.microsoft.com/VisualStudio/2005/CodeSnippet">
  <CodeSnippet Format="1.0.0">
    <Header>
      <Title>Define a Test Method</Title>
      <Author>Tim Murphy</Author>
      <Description>Defines a Test Method with AAA comments.</Description>
      <Shortcut>TM</Shortcut>
    </Header>
    <Snippet>
      <Declarations>
        <Literal>
          <ID>Method</ID>
          <Type>String</Type>
          <ToolTip>Replace this with method to be tested.</ToolTip>
          <Default>Method</Default>
        </Literal>
        <Literal>
          <ID>Expects</ID>
          <Type>String</Type>
          <ToolTip>Replace this with what the method is expected to do.</ToolTip>
          <Default>Expects</Default>
        </Literal>
        <Object>
          <ID>When</ID>
          <Type>String</Type>
          <ToolTip>Replace this with the condition the method is testing.</ToolTip>
          <Default>When</Default>
        </Object>
      </Declarations>
      <Code Language="VB" Kind="method decl">
          <![CDATA[<TestMethod()> Public Sub $Method$_$Expects$_$When$()

        ' Arrange
        ' ---------------------------------------------------------------------

        ' Act
        ' ---------------------------------------------------------------------

        ' Assert
        ' ---------------------------------------------------------------------

    End Sub]]></Code>
    </Snippet>
  </CodeSnippet>
</CodeSnippets>

After installing the snippet just type tm then tab and you get:

<TestMethod()> Public Sub Method_Expects_When()

    ' Arrange
    ' ---------------------------------------------------------------------

    ' Act
    ' ---------------------------------------------------------------------

    ' Assert
    ' ---------------------------------------------------------------------

End Sub

Example: DataGridView

Sun, 08 May 2011 17:26:29 GMT

This is the first in a series of examples on databinding, MVC and related matters using .NET Framework, Visual Studio 2008 & VB.NET.

The purpose of this example is to show how to quickly and easily develop a form with a DataGridView, Navigation and the ability to load data. It is purposely simplistic in nature and future examples will provide best practice and real world examples.

Source code for all examples can be found at http://26tp.codeplex.com. 26tp.Examples.DataGridView is the project for this blog.

Models.Contact

Models.Contact is a very simple class with the following properties:

FirstName
LastName
Birthday
Cars
Age: Read only, calculated from their birthday to today.
FullName: Read only, FirstName + “ “ + LastName.

Excerpt of class.

Namespace Models

    Public Class Contact

        Private mFirstName As String
        Public Property FirstName() As String
            Get
                Return mFirstName
            End Get
            Set(ByVal value As String)
                mFirstName = value
            End Set
        End Property

        ...

        Public ReadOnly Property Age() As Long?
            Get

                If Not mBirthday.HasValue Then
                    Return Nothing
                End If

                Dim years = Now.Year - mBirthday.Value.Year

                If New Date(mBirthday.Value.Year, Now.Month, Now.Day) < mBirthday.Value Then
                    years -= 1
                End If

                Return years

            End Get
        End Property

        Public ReadOnly Property FullName() As String
            Get
                Return CStr(mFirstName + " " + mLastName).Trim
            End Get
        End Property

    End Class

End Namespace

Creating the DataGridView

Create a blank form.
Add a StatusStrip.
Add a Panel docked to the right. This will be used to host buttons and labels that will be created later.
Add Models.Contact to Data Sources via the Data –> Add New Data Source menu option.
Finally drag the Models.Contact Data Source onto the window and dock it into the Parent Container.

Hit F5 and you have a working DataGridView. FullName changes when you enter FirstName and/or LastName. Age changes when you enter a Birthday.

Load Existing Data

To load existing data the ContactBindingSource.DataSource needs to be updated.

Public Class Contacts

    Private mContacts As New BindingList(Of Models.Contact)

    Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)

        Me.ContactBindingSource.DataSource = mContacts

    End Sub

    Private Sub LoadButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles LoadButton.Click

        mContacts = New BindingList(Of Models.Contact)((New Models.ContactRepository).FindAll)
        Me.ContactBindingSource.DataSource = mContacts

    End Sub

End Class

In the above code the mContacts was introduced as the container for our fake contacts. A BindingList is used so any changes we make to mContacts will be recognised by ContactBindingSource and shown in the data grid.

The ContactRepository.FindAll method simply returns a list of fake contacts.

Namespace Models

    Public Class ContactRepository

        Public Function FindAll() As List(Of Contact)

            Dim list = New List(Of Contact)

            list.Add(New Contact With {.FirstName = "Edna", .LastName = "Kimble", .Birthday = New Date(1957, 12, 24)})
            list.Add(New Contact With {.FirstName = "Maria", .LastName = "Fenimore", .Birthday = New Date(1946, 7, 7)})
            list.Add(New Contact With {.FirstName = "John", .LastName = "Bateman", .Birthday = New Date(1970, 2, 8)})
            list.Add(New Contact With {.FirstName = "James", .LastName = "Ferguson", .Birthday = New Date(1967, 7, 8)})
            list.Add(New Contact With {.FirstName = "Debra", .LastName = "Lyons", .Birthday = New Date(2010, 1, 1)})

            Return list

        End Function

    End Class

End Namespace

The next blog in the Examples series will look at implementing INotifyPropertyChanged.

Example: Implementing INotifyPropertyChanged

Sun, 08 May 2011 17:26:28 GMT

In the previous example DataGridView we had a very simple Models.Contact class being displayed in a DataGridView. In this post we will look at how and why to implement INotifyPropertyChanged interface on the Models.Contact.

Why

It is time to be generous and give away some cars :-)

Private Sub GiveCarButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles GiveCarButton.Click

    Dim contact As Models.Contact = Me.ContactBindingSource.Current

    If contact Is Nothing Then

        MessageBox.Show("Must be on a current record to give away a car.", "Car Give Away", MessageBoxButtons.OK, MessageBoxIcon.Information)

    End If

    If MessageBox.Show(String.Format("Give a car away to '{0}'?", contact.FullName), "Car Give Away", MessageBoxButtons.YesNo, MessageBoxIcon.Question) = Windows.Forms.DialogResult.Yes Then

        contact.Cars += 1

    End If

End Sub

Pretty simple but the grid/edit window that raises this event will not display the new number cars. Updating Models.Contacts to implement the INotifyPropertyChanged interface will fix this problem.

How

Imports System.ComponentModel

Namespace Models

    Public Class Contact
        Implements INotifyPropertyChanged

        Public Event PropertyChanged(ByVal sender As Object, ByVal e As System.ComponentModel.PropertyChangedEventArgs) Implements System.ComponentModel.INotifyPropertyChanged.PropertyChanged

        ...

        Private mCars As Integer
        Public Property Cars() As Integer
            Get
                Return mCars
            End Get
            Set(ByVal value As Integer)
                If mCars <> value Then
                    mCars = value
                    RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs("Cars"))
                End If
            End Set
        End Property

        ...

    End Class

End Namespace

With the above change to our property any control that is bound to Models.Contact will be aware of any changes made to the underlying data. We need to update every property and in the codes current form that would be time consuming and error prone. A future post will look at refactoring Models.Contact.

Example

The example can be downloaded from http://26tp.codeplex.com, project 26tp.Examples.ImplementINotifyPropertyChanged.

This example has two forms, Grid & Edit. Each form has a Notify Property Changes checkbox. Try giving a car away with the checkbox ticked and unticked to see the effect of raise the PropertyChanged event.

Building a MVP Framework: Table of Contents

Sun, 08 May 2011 17:26:27 GMT

Lately I’ve spent a reasonable amount of time with ASP.NET MVC and grown to love the pattern. My current project is a Windows Form application and in need of help from a similar. Having spent the last two days researching the topic I’ve not been able to find a framework that I’m satisfied. Largely they are under documented or overly complex. I’m trying to make development easier that harder!

To quote a Scott Hansleman blog post I read recently “If you don't like something, fix it.”. I have a very pressing need and short deadline for the current project. In other words to begin with it’s going to be a hack fest. The main concern will be to get the job done, worry about the pretty stuff later on.

Wish me luck.

Building a MVP Framework: Part 1: The Goals

Sun, 08 May 2011 17:26:26 GMT

In Part 1 of the Building a MVP Framework series I’m going to define the goals of the sample application and the framework itself.

Framework Goals

The goals of any Framework are (or at least should be) determined by the requirements of the applications that will use the Framework. The MVP Framework must address the following needs.

Separation of UI and Business Logic code.
Thin UI.
Easy to implement.
Easy to Unit Test a very high percentage of the application.

Sample Application Goals

In this series I’ll be using the Chinook Database imported into a SQLite database. Initially the application will have ~~five~~ six forms.

Application Window.
Welcome Dialog.
Create SQLite database from SQL file.
Edit Artists. Very simple form allowing scrolling throw the list of Artists and editing.
Grid of Artists. Very simple form display a grid of Artists with editing.
Artists Explorer. The explorer will have three panels: Tree, Grid & Edit. The explorer will use and display data from the Artist, Album, Track, PlaylistTrack & Playlist tables of the Chinook Database.

In Part 2, The Application Window, I’ll look at the first implementation of MVP.

Building a MVP Framework: Part 2: The Application Window

Sun, 08 May 2011 17:26:25 GMT

In Part 1 of series I said there would be five forms; in fact there are six. I forgot about the application window. The application window needs a title and link in the status bar to this series’ table of contents.

In Part 2 of the series I’m going to design and implement a simple Welcome Dialog. Personally I hate Welcome Dialogs but its nice and simple to get the ball rolling.

The dialog will display:

Application Name
Version
Web Link
OK button

Application Startup

Later in this post I’ll describe the Presenter class but for now suffice to say it is god in an MVP application. That being the case we need to change the default startup routine of the WinForm project. Create a module with a public sub main:

Public Module Main

    Public Sub Main()

        Dim appWindowPresenter = New AppWindowPresenter

        Application.Run(appWindowPresenter.StartupForm)

    End Sub

End Module

The name of the module is not important but the procedure must be named Main.

Next go into the project properties and untick the Enable application framework option and select Sub Main as the Startup object (must be done in that order.

The Presenter

As previously mentioned the Presenter is god. It is responsible for constructing the form, serving data to the form and responding to UI events.

Public Class AppWindowPresenter

    Private mStartupForm As AppWindow

    Public Sub New()
        mStartupForm = New AppWindow(me)
    End Sub

    Public ReadOnly Property StartupForm() As AppWindow
        Get
            Return mStartupForm
        End Get
    End Property

End Class

As you can see in the above code the AppWindowPresenter has a reference to the AppWindow form is constructs and AppWindow has a reference to AppWindowPresenter. This is required so when form receives a UI event it can talk to the presenter and the presenter can talk back to the window.

The Model

The AppWindow needs to set the text for it’s title and status bars; it does this via a Model. A Model is simple a data object, entity call it what you like. In this series of example class names ending with Model refer to object holding raw data from the database. Classes ending with ViewModel are objects tailor made for a View.

The AppWindowViewModel has just three readonly properties Name, BlogTitle and BlogURL.

Binding The Data

Now we have the model and the application window being displayed we need the application window to update itself with the values in the model. A quick change the presenter constructor:

Public Sub New()
    mModel = New AppWindowViewModel
    mStartupForm = New AppWindow(Me)
    mStartupForm.BindData()
End Sub

Followed by adding AppWindow.BindData() method:

Public Sub BindData()
    Me.Text = mPresenter.Model.Name
    Me.BlogToolStripStatusLabel.Text = mPresenter.Model.BlogTitle
End Sub

Now when the application starts the application title bar and status bar are updated with the required buttons.

The Unit Tests

So far I’ve not mention unit tests. Well of course I’ve been writing this as we go. As you can imagine the unit tests for the AppWindowPresenter and AppWindowViewModel class are very quick and easy to implement. The AppWindow tests are equally easy.

<TestClass()> Public Class AppWindow_Tests

    <TestMethod()> Public Sub CanConstruct()

        ' Arrange

        ' Act
        Dim value = New AppWindow(New AppWindowPresenter)

        ' Assert
        value.ShouldNotBeNull()

    End Sub

    <TestMethod()> Public Sub AppWindow_BindsData()

        ' Arrange
        Dim presenter = New AppWindowPresenter

        ' Act
        Dim frm = presenter.StartupForm()

        ' Assert
        frm.Text.ShouldEqual(presenter.Model.Name)
        frm.BlogToolStripStatusLabel.Text.ShouldEqual(presenter.Model.BlogTitle)

    End Sub

End Class

As you can see the we have been able to test every method in the AppWindow with very little pain or fanfare.

Source Code

Source code is available for this post via SVN:

svn export "https://26tp.svn.codeplex.com/svn/tags/Building a MVP Framework - Part 2"

Or to get the latest copy of the complete series code:

svn export https://26tp.svn.codeplex.com/svn/trunk/

View the 26tp.Examples.MVP project via the 26tp.Examples.sln solution.

Summary

In this post we can created our first Presenter, Model & Form classes along with accompanying unit tests. So far the framework has meet all the goals set out in Part 1.

Has it been worth it. It would have been quicker and easy just to design the AppWindow in Visual Studio, use the properties window to set the required values and we could write unit tests for this. But one positive side effect is we can easily read the code to see exactly have properties have been set. Using the MVP pattern we are able to create the AppWindow with the designer and the only properties we change in the designer is the name of the controls.

In the next post, The About Dialog, we will look at using a BindingSource to bind the model to the form.

How to install Python and CGI scripts on Windows Server 2003

Sun, 08 May 2011 17:26:24 GMT

Download and install required version of Python.
Open Internet Information Services.
Open the Properties dialog for web site that required Python CGI scripts.
Go to the Home Directory tab.
Ensure Execute permissions is set to Scripts Only.
Click the Configuration button and select the Mappings tab.
Click Add… button.
Set the Executable value to C:\Python26\python.exe -u "%s %s" (Change path appropriately)
Set the Extension value to .cgi.
Set Verbs to All Verbs.
Tick Script engine on.
Tick Verify that file exists on.
Click OK to return to the Application Configuration dialog.
Click OK to return to the web site Properties dialog.
Click OK to return to Internet Information Services manager.

Install a simple CGI script to test the installation.

print 'Status: 200 OK'
print 'Content-type: text/html'
print
 
print '<html><head>'
print ''
print '<h1>It works!</h1>'
print ''
print ''

Point your browser to the test script and hey presto it should be working.